SPI Lcd Library

The mikroBasic PRO for 8051 provides a library for communication with Lcd (with HD44780 compliant controllers) in 4-bit mode via SPI interface.

For creating a custom set of Lcd characters use Lcd Custom Character Tool.

Note: The library uses the SPI module for communication. The user must initialize the SPI module before using the SPI Lcd Library.

Note: This Library is designed to work with the mikroElektronika's Serial Lcd Adapter Board pinout. See schematic at the bottom of this page for details.

External dependencies of SPI Lcd Library

The implementation of SPI Lcd Library routines is based on Port Expander Library routines.

External dependencies are the same as Port Expander Library external dependencies.

SPI_Lcd_Config

Prototype	sub procedure SPI_Lcd_Config(dim DeviceAddress as byte)
Returns	Nothing.
Description	Initializes the Lcd module via SPI interface. Parameters : `DeviceAddress:` spi expander hardware address, see schematic at the bottom of this page
Requires	`SPExpanderCS` and `SPExpanderRST` variables must be defined before using this function. The SPI module needs to be initialized. See SPIx_Init and SPIx_Init_Advanced routines.
Example	' port expander pinout definition dim SPExpanderCS as sbit at P1_1_bit SPExpanderRST as sbit at P1_0_bit ... SPI1_Init() ' initialize spi SPI_Lcd_Config(0) ' initialize lcd over spi interface

SPI_Lcd_Out

Prototype	sub procedure SPI_Lcd_Out(dim row as byte, dim column as byte, dim byref text as string[19])
Returns	Nothing.
Description	Prints text on the Lcd starting from specified position. Both string variables and literals can be passed as a text. Parameters : `row:` starting position row number `column:` starting position column number `text:` text to be written
Requires	Lcd needs to be initialized for SPI communication, see SPI_Lcd_Config routines.
Example	' Write text "Hello!" on Lcd starting from row 1, column 3: SPI_Lcd_Out(1, 3, "Hello!")

SPI_Lcd_Out_Cp

Prototype	sub procedure SPI_Lcd_Out_CP(dim text as string[19])
Returns	Nothing.
Description	Prints text on the Lcd at current cursor position. Both string variables and literals can be passed as a text. Parameters : `text:` text to be written
Requires	Lcd needs to be initialized for SPI communication, see SPI_Lcd_Config routines.
Example	' Write text "Here!" at current cursor position: SPI_Lcd_Out_CP("Here!")

SPI_Lcd_Chr

Prototype	sub procedure SPI_Lcd_Chr(dim Row as byte, dim Column as byte, dim Out_Char as byte)
Returns	Nothing.
Description	Prints character on Lcd at specified position. Both variables and literals can be passed as character. Parameters : `Row:` writing position row number `Column:` writing position column number `Out_Char:` character to be written
Requires	Lcd needs to be initialized for SPI communication, see SPI_Lcd_Config routines.
Example	' Write character "i" at row 2, column 3: SPI_Lcd_Chr(2, 3, 'i')

SPI_Lcd_Chr_Cp

Prototype	sub procedure SPI_Lcd_Chr_CP(dim Out_Char as byte)
Returns	Nothing.
Description	Prints character on Lcd at current cursor position. Both variables and literals can be passed as character. Parameters : `Out_Char:` character to be written
Requires	Lcd needs to be initialized for SPI communication, see SPI_Lcd_Config routines.
Example	' Write character "e" at current cursor position: SPI_Lcd_Chr_Cp('e')

SPI_Lcd_Cmd

Prototype	sub procedure SPI_Lcd_Cmd(dim out_char as byte)
Returns	Nothing.
Description	Sends command to Lcd. Parameters : `out_char:` command to be sent Note: Predefined constants can be passed to the function, see Available Lcd Commands.
Requires	Lcd needs to be initialized for SPI communication, see SPI_Lcd_Config routines.
Example	' Clear Lcd display: SPI_Lcd_Cmd(_LCD_CLEAR)

Available Lcd Commands

Lcd Command	Purpose
_LCD_FIRST_ROW	Move cursor to the 1st row
_LCD_SECOND_ROW	Move cursor to the 2nd row
_LCD_THIRD_ROW	Move cursor to the 3rd row
_LCD_FOURTH_ROW	Move cursor to the 4th row
_LCD_CLEAR	Clear display
_LCD_RETURN_HOME	Return cursor to home position, returns a shifted display to its original position. Display data RAM is unaffected.
_LCD_CURSOR_OFF	Turn off cursor
_LCD_UNDERLINE_ON	Underline cursor on
_LCD_BLINK_CURSOR_ON	Blink cursor on
_LCD_MOVE_CURSOR_LEFT	Move cursor left without changing display data RAM
_LCD_MOVE_CURSOR_RIGHT	Move cursor right without changing display data RAM
_LCD_TURN_ON	Turn Lcd display on
_LCD_TURN_OFF	Turn Lcd display off
_LCD_SHIFT_LEFT	Shift display left without changing display data RAM
_LCD_SHIFT_RIGHT	Shift display right without changing display data RAM

Library Example

This example demonstrates how to communicate Lcd via the SPI module, using serial to parallel convertor MCP23S17.

program SPI_Lcd

dim text as char[16]
dim counter as byte

' Port Expander module connections
dim SPExpanderRST as sbit at P1_0_bit
dim SPExpanderCS  as sbit at P1_1_bit
' End Port Expander module connections

sub procedure Move_Delay()                  ' Function used for text moving
  Delay_ms(500)                       ' You can change the moving speed here
end sub

main:
  text = "mikroElektronika"
  SPI1_Init()                         ' Initialize SPI
  SPI_Lcd_Config(0)                   ' Initialize LCD over SPI interface
  SPI_Lcd_Cmd(_LCD_CLEAR)             ' Clear display
  SPI_Lcd_Cmd(_LCD_CURSOR_OFF)        ' Turn cursor off
  SPI_Lcd_Out(1,6, "mikroE")          ' Print text to LCD, 1st row, 6th column
  SPI_Lcd_Chr_CP("!")                 ' Append "!"
  SPI_Lcd_Out(2,1, text)              ' Print text to LCD, 2nd row, 1st column

  '  SPI_Lcd_Out(3,1,"mikroE")       ' For LCD with more than two rows
  '  SPI_Lcd_Out(4,15,"mikroE")      ' For LCD with more than two rows

  ' Moving text
  for counter = 0 to 3               ' Move text to the right 4 times
    SPI_Lcd_Cmd(_LCD_SHIFT_RIGHT)
    Move_Delay()
  next counter

  while TRUE                         ' Endless loop
    for counter = 0 to 6             ' Move text to the left 7 times
      SPI_Lcd_Cmd(_LCD_SHIFT_LEFT)
      Move_Delay()
    next counter

    for counter = 0 to 6             ' Move text to the right 7 times
      SPI_Lcd_Cmd(_LCD_SHIFT_RIGHT)
      Move_Delay()
    next counter
  wend
end.

HW Connection

SPI Lcd HW connection

Want more examples and libraries?
Find them on