Lcd Library

The mikroBasic PRO for 8051 provides a library for communication with Lcds (with HD44780 compliant controllers) through the 4-bit interface. An example of Lcd connections is given on the schematic at the bottom of this page.

For creating a set of custom Lcd characters use Lcd Custom Character Tool.

External dependencies of Lcd Library

The following variables must be defined in all projects using Lcd Library :	Description :	Example :
`dim LCD_RS as sbit bdata sfr external`	Register Select line.	`dim LCD_RS as sbit at P2_0_bit`
`dim LCD_EN as sbit bdata sfr external`	Enable line.	`dim LCD_EN as sbit at P2_1_bit`
`dim LCD_D7 as sbit bdata sfr external`	Data 7 line.	`dim LCD_D7 as sbit at P2_5_bit`
`dim LCD_D6 as sbit bdata sfr external`	Data 6 line.	`dim LCD_D6 as sbit at P2_4_bit`
`dim LCD_D5 as sbit bdata sfr external`	Data 5 line.	`dim LCD_D5 as sbit at P2_3_bit`
`dim LCD_D4 as sbit bdata sfr external`	Data 4 line.	`dim LCD_D4 as sbit at P2_2_bit`

Lcd_Init

Prototype	sub procedure Lcd_Init()
Returns	Nothing.
Description	Initializes Lcd module.
Requires	Global variables: `LCD_D7:` data bit 7 `LCD_D6:` data bit 6 `LCD_D5:` data bit 5 `LCD_D4:` data bit 4 `RS:` register select (data/instruction) signal pin `EN:` enable signal pin must be defined before using this function.
Example	' lcd pinout settings dim LCD_RS as sbit at P2_0_bit LCD_EN as sbit at P2_1_bit LCD_D7 as sbit at P2_5_bit LCD_D6 as sbit at P2_4_bit LCD_D5 as sbit at P2_3_bit LCD_D4 as sbit at P2_2_bit ... Lcd_Init()

Lcd_Out

Prototype	sub procedure Lcd_Out(dim row as byte, dim column as byte, dim byref text as string[20])
Returns	Nothing.
Description	Prints text on Lcd starting from specified position. Both string variables and literals can be passed as a text. Parameters : `row:` starting position row number `column:` starting position column number `text:` text to be written
Requires	The Lcd module needs to be initialized. See Lcd_Init routine.
Example	' Write text "Hello!" on Lcd starting from row 1, column 3: Lcd_Out(1, 3, "Hello!")

Lcd_Out_CP

Prototype	sub procedure Lcd_Out_Cp(dim byref text as string[19])
Returns	Nothing.
Description	Prints text on Lcd at current cursor position. Both string variables and literals can be passed as a text. Parameters : `text:` text to be writtn
Requires	The Lcd module needs to be initialized. See Lcd_Init routine.
Example	' Write text "Here!" at current cursor position: Lcd_Out_Cp("Here!")

Lcd_Chr

Prototype	sub procedure Lcd_Chr(dim row as byte, dim column as byte, dim out_char as byte)
Returns	Nothing.
Description	Prints character on Lcd at specified position. Both variables and literals can be passed as a character. Parameters : `row:` writing position row number `column:` writing position column number `out_char:` character to be written
Requires	The Lcd module needs to be initialized. See Lcd_Init routine.
Example	' Write character "i" at row 2, column 3: Lcd_Chr(2, 3, 'i')

Lcd_Chr_CP

Prototype	sub procedure Lcd_Chr_Cp(dim out_char as byte)
Returns	Nothing.
Description	Prints character on Lcd at current cursor position. Both variables and literals can be passed as a character. Parameters : `out_char:` character to be written
Requires	The Lcd module needs to be initialized. See Lcd_Init routine.
Example	' Write character "e" at current cursor position: Lcd_Chr_Cp('e')

Lcd_Cmd

Prototype	sub procedure Lcd_Cmd(dim out_char as byte)
Returns	Nothing.
Description	Sends command to Lcd. Parameters : `out_char:` command to be sent Note: Predefined constants can be passed to the function, see Available Lcd Commands.
Requires	The Lcd module needs to be initialized. See Lcd_Init table.
Example	' Clear Lcd display: Lcd_Cmd(_LCD_CLEAR)

Available Lcd Commands

Lcd Command	Purpose
_LCD_FIRST_ROW	Move cursor to the 1st row
_LCD_SECOND_ROW	Move cursor to the 2nd row
_LCD_THIRD_ROW	Move cursor to the 3rd row
_LCD_FOURTH_ROW	Move cursor to the 4th row
_LCD_CLEAR	Clear display
_LCD_RETURN_HOME	Return cursor to home position, returns a shifted display to its original position. Display data RAM is unaffected.
_LCD_CURSOR_OFF	Turn off cursor
_LCD_UNDERLINE_ON	Underline cursor on
_LCD_BLINK_CURSOR_ON	Blink cursor on
_LCD_MOVE_CURSOR_LEFT	Move cursor left without changing display data RAM
_LCD_MOVE_CURSOR_RIGHT	Move cursor right without changing display data RAM
_LCD_TURN_ON	Turn Lcd display on
_LCD_TURN_OFF	Turn Lcd display off
_LCD_SHIFT_LEFT	Shift display left without changing display data RAM
_LCD_SHIFT_RIGHT	Shift display right without chnging display data RAM

Library Example

The following code demonstrates usage of the Lcd Library routines:

program  Lcd_Test

' LCD module connections
dim LCD_RS as sbit at P2_0_bit
dim LCD_EN as sbit at P2_1_bit

dim LCD_D4 as sbit at P2_2_bit
dim LCD_D5 as sbit at P2_3_bit
dim LCD_D6 as sbit at P2_4_bit
dim LCD_D7 as sbit at P2_5_bit
' End LCD module connections

dim txt1 as char[16]
    txt2 as char[9]
    txt3 as char[8]
    txt4 as char[7]
    i    as byte                    ' Loop variable

sub procedure Move_Delay()          ' Function used for text moving
  Delay_ms(500)                     ' You can change the moving speed here
end sub

main:
  txt1 = "mikroElektronika"
  txt2 = "Easy8051B"
  txt3 = "Lcd4bit"
  txt4 = "example"
  Lcd_Init()                        ' Initialize LCD
  Lcd_Cmd(_LCD_CLEAR)               ' Clear display
  Lcd_Cmd(_LCD_CURSOR_OFF)          ' Cursor off
  LCD_Out(1,6,txt3)                 ' Write text in first row
  LCD_Out(2,6,txt4)                 ' Write text in second row
  Delay_ms(2000)
  Lcd_Cmd(_LCD_CLEAR)               ' Clear display

  LCD_Out(1,1,txt1)                 ' Write text in first row
  LCD_Out(2,4,txt2)                 ' Write text in second row
  Delay_ms(500)

  ' Moving text
  for i = 0 to 3                    ' Move text to the right 4 times
    Lcd_Cmd(_LCD_SHIFT_RIGHT)
    Move_Delay()
  next i

  while TRUE                        ' Endless loop
    for i = 0 to 6                  ' Move text to the left 7 times
      Lcd_Cmd(_LCD_SHIFT_LEFT)
      Move_Delay()
    next i

    for i = 0 to 6                  ' Move text to the right 7 times
      Lcd_Cmd(_LCD_SHIFT_RIGHT)
      Move_Delay()
    next i

  wend
end.

Lcd HW connection

Want more examples and libraries?
Find them on